dnl configure.ac
dnl
dnl xfce4-screenshooter-plugin - Plugin for the Xfce panel
dnl

m4_define([xfce4_screenshooter_plugin_version_major], [1])
m4_define([xfce4_screenshooter_plugin_version_minor], [3])
m4_define([xfce4_screenshooter_plugin_version_micro], [9])
m4_define([xfce4_screenshooter_plugin_version_nano],  [0]) dnl leave this empty to have no nano version
m4_define([xfce4_screenshooter_plugin_version_build], [r@REVISION@])
m4_define([xfce4_screenshooter_plugin_version_tag],   [svn])
m4_define([xfce4_screenshooter_plugin_version], [xfce4_screenshooter_plugin_version_major().xfce4_screenshooter_plugin_version_minor().xfce4_screenshooter_plugin_version_micro()ifelse(xfce4_screenshooter_plugin_version_nano(), [], [], [.xfce4_screenshooter_plugin_version_nano()])ifelse(xfce4_screenshooter_plugin_version_tag(), [svn], [xfce4_screenshooter_plugin_version_tag()-xfce4_screenshooter_plugin_version_build()], [xfce4_screenshooter_plugin_version_tag()])])

AC_INIT([xfce4-screenshooter-plugin], [xfce4_screenshooter_plugin_version], [http://bugzilla.xfce.org/], [xfce4-screenshooter-plugin])

AM_INIT_AUTOMAKE([1.8 dist-bzip2 tar-ustar])
AM_CONFIG_HEADER([config.h])

AM_MAINTAINER_MODE

dnl Check for UNIX variants
AC_AIX
AC_ISC_POSIX
AC_MINIX

dnl Check for basic programs
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_INTLTOOL
AC_PROG_LIBTOOL

dnl Check for standard header files
AC_HEADER_STDC

dnl Check for xfce4-panel
XDT_CHECK_PACKAGE([LIBXFCE4PANEL], [libxfce4panel-1.0], [4.3.22])

dnl Check for xfce4util
XDT_CHECK_PACKAGE([LIBXFCE4UTIL], [libxfce4util-1.0], [4.4])

dnl Check for xfcegui4
XDT_CHECK_PACKAGE([LIBXFCEGUI4], [libxfcegui4-1.0], [4.4])

dnl Check for x11proto
XDT_CHECK_PACKAGE([X11PROTO_CORE], [xproto], [7])

dnl Check for gtk
XDT_CHECK_PACKAGE([GTK], [gtk+-2.0], [2.10.0])

dnl Check for glib
XDT_CHECK_PACKAGE([GLIB], [glib-2.0], [2.12.0])

dnl Optionnal check for gio
XDT_CHECK_OPTIONAL_PACKAGE([GIO], [gio-2.0], [2.16])

dnl Translations
XDT_I18N([ar ca cs da de el en_GB es eu fr gl hr hu id ja lv nb_NO nl pl pt_BR pt_PT sq uk ur zh_TW])

dnl Check for debugging support
XDT_FEATURE_DEBUG()

AC_OUTPUT([
Makefile
icons/Makefile
icons/48x48/Makefile
icons/scalable/Makefile
lib/Makefile
src/Makefile
panel-plugin/Makefile
po/Makefile.in
])

dnl ***************************
dnl *** Print configuration ***
dnl ***************************

echo "Build Configuration:"

if test x"$GIO_FOUND" = x"yes"; then
echo "* Open with support:             yes"
else
echo "* Open with support:             no"
fi

